Direct function

"Dfns" redirects here. For the political entity sometimes known as the Democratic Federation of Northern Syria, see Rojava.

A direct function (dfn, pronounced "dee fun") is an alternative way to define a function and operator (a higher-order function) in the programming language APL. A direct operator can also be called a dop (pronounced "dee op"). They were invented by John Scholes in 1996. They are a unique combination of array programming, higher-order function, and functional programming, and are a major distinguishing advance of early 21st century APL over prior versions.

A dfn is a sequence of possibly guarded expressions (or just a guard) between <syntaxhighlight lang="apl" class="" style="" inline="1">{</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">}</syntaxhighlight>, separated by <syntaxhighlight lang="apl" class="" style="" inline="1">⋄</syntaxhighlight> or new-lines, wherein <syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight> denotes the left argument and <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> the right, and <syntaxhighlight lang="apl" class="" style="" inline="1">∇</syntaxhighlight> denotes recursion (function self-reference). For example, the function <syntaxhighlight lang="apl" class="" style="" inline="1">PT</syntaxhighlight> tests whether each row of <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> is a Pythagorean triplet (by testing whether the sum of squares equals twice the square of the maximum).

<syntaxhighlight lang=apl>

  PT← {(+/⍵*2)=2×(⌈/⍵)*2}
  PT 3 4 5

1

  x
4  5  3
3 11  6
5 13 12

17 16 8 11 12 4 17 15 8

  PT x

1 0 1 0 0 1 </syntaxhighlight>

The factorial function as a dfn:

<syntaxhighlight lang=apl>

  fact← {0=⍵:1 ⋄ ⍵×∇ ⍵-1}
  fact 5

120

  fact¨ ⍳10    ⍝ fact applied to each element of 0 to 9

1 1 2 6 24 120 720 5040 40320 362880 </syntaxhighlight>

Description

The rules for dfns are summarized by the following "reference card":

<syntaxhighlight lang="apl" class="" style="" inline="1">{⍺ function ⍵}</syntaxhighlight>	<syntaxhighlight lang="apl" class="" style="" inline="1">{⍺⍺ operator ⍵⍵}</syntaxhighlight>	<syntaxhighlight lang="apl" class="" style="" inline="1">:</syntaxhighlight>   guard
<syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight>  left argument	<syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight>  left operand	<syntaxhighlight lang="apl" class="" style="" inline="1">::</syntaxhighlight>  error-guard
<syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight>  right argument	<syntaxhighlight lang="apl" class="" style="" inline="1">⍵⍵</syntaxhighlight>  right operand	<syntaxhighlight lang="apl" class="" style="" inline="1">⍺←</syntaxhighlight>  default left argument
<syntaxhighlight lang="apl" class="" style="" inline="1">∇</syntaxhighlight>  self-reference	<syntaxhighlight lang="apl" class="" style="" inline="1">∇∇</syntaxhighlight>  self-reference	<syntaxhighlight lang="apl" class="" style="" inline="1">s←</syntaxhighlight>  shy result

A dfn is a sequence of possibly guarded expressions (or just a guard) between <syntaxhighlight lang="apl" class="" style="" inline="1">{</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">}</syntaxhighlight>, separated by <syntaxhighlight lang="apl" class="" style="" inline="1">⋄</syntaxhighlight> or new-lines. <syntaxhighlight lang=apl> expression guard: expression guard: </syntaxhighlight> The expressions and/or guards are evaluated in sequence. A guard must evaluate to a 0 or 1; its associated expression is evaluated if the value is 1. A dfn terminates after the first unguarded expression which does not end in assignment, or after the first guarded expression whose guard evaluates to 1, or if there are no more expressions. The result of a dfn is that of the last evaluated expression. If that last evaluated expression ends in assignment, the result is "shy"—not automatically displayed in the session.

Names assigned in a dfn are local by default, with lexical scope.

<syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight> denotes the left function argument and <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> the right; <syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight> denotes the left operand and <syntaxhighlight lang="apl" class="" style="" inline="1">⍵⍵</syntaxhighlight> the right. If <syntaxhighlight lang="apl" class="" style="" inline="1">⍵⍵</syntaxhighlight> occurs in the definition, then the dfn is a dyadic operator; if only <syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight> occurs but not <syntaxhighlight lang="apl" class="" style="" inline="1">⍵⍵</syntaxhighlight>, then it is a monadic operator; if neither <syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight> or <syntaxhighlight lang="apl" class="" style="" inline="1">⍵⍵</syntaxhighlight> occurs, then the dfn is a function.

The special syntax <syntaxhighlight lang="apl" class="" style="" inline="1">⍺←expression</syntaxhighlight> is used to give a default value to the left argument if a dfn is called monadically, that is, called with no left argument. The <syntaxhighlight lang="apl" class="" style="" inline="1">⍺←expression</syntaxhighlight> is not evaluated otherwise.

<syntaxhighlight lang="apl" class="" style="" inline="1">∇</syntaxhighlight> denotes recursion or self-reference by the function, and <syntaxhighlight lang="apl" class="" style="" inline="1">∇∇</syntaxhighlight> denotes self-reference by the operator. Such denotation permits anonymous recursion.

Error trapping is provided through error-guards, <syntaxhighlight lang="apl" class="" style="" inline="1">errnums::expression</syntaxhighlight>. When an error is generated, the system searches dynamically through the calling functions for an error-guard that matches the error. If one is found, the execution environment is unwound to its state immediately prior to the error-guard's execution and the associated expression of the error-guard is evaluated as the result of the dfn.

Additional descriptions, explanations, and tutorials on dfns are available in the cited articles.

Examples

The examples here illustrate different aspects of dfns. Additional examples are found in the cited articles.

Default left argument

The function <syntaxhighlight lang="apl" class="" style="" inline="1">{⍺+0j1×⍵}</syntaxhighlight> adds <syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight> to <syntaxhighlight lang="apl" class="" style="" inline="1">0j1</syntaxhighlight> (i or ${\sqrt {-1}}$) times <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight>.

<syntaxhighlight lang=apl>

  3 {⍺+0j1×⍵} 4

3J4

  ∘.{⍺+0j1×⍵}⍨ ¯2+⍳5

¯2J¯2 ¯2J¯1 ¯2 ¯2J1 ¯2J2 ¯1J¯2 ¯1J¯1 ¯1 ¯1J1 ¯1J2

0J¯2  0J¯1  0  0J1  0J2
1J¯2  1J¯1  1  1J1  1J2
2J¯2  2J¯1  2  2J1  2J2

</syntaxhighlight>

The significance of this function can be seen as follows:

Complex numbers can be constructed as ordered pairs of real numbers, similar to how integers can be constructed as ordered pairs of natural numbers and rational numbers as ordered pairs of integers. For complex numbers, <syntaxhighlight lang="apl" class="" style="" inline="1">{⍺+0j1×⍵}</syntaxhighlight> plays the same role as <syntaxhighlight lang="apl" class="" style="" inline="1">-</syntaxhighlight> for integers and <syntaxhighlight lang="apl" class="" style="" inline="1">÷</syntaxhighlight> for rational numbers.

Moreover, analogous to that monadic <syntaxhighlight lang="apl" class="" style="" inline="1">-⍵</syntaxhighlight> ⇔ <syntaxhighlight lang="apl" class="" style="" inline="1">0-⍵</syntaxhighlight> (negate) and monadic <syntaxhighlight lang="apl" class="" style="" inline="1">÷⍵</syntaxhighlight> ⇔ <syntaxhighlight lang="apl" class="" style="" inline="1">1÷⍵</syntaxhighlight> (reciprocal), a monadic definition of the function is useful, effected by specifying a default value of 0 for <syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight>: if <syntaxhighlight lang="apl" class="" style="" inline="1">j←{⍺←0 ⋄ ⍺+0j1×⍵}</syntaxhighlight>, then <syntaxhighlight lang="apl" class="" style="" inline="1">j ⍵</syntaxhighlight> ⇔ <syntaxhighlight lang="apl" class="" style="" inline="1">0 j ⍵</syntaxhighlight> ⇔ <syntaxhighlight lang="apl" class="" style="" inline="1">0+0j1×⍵</syntaxhighlight>.

<syntaxhighlight lang=apl>

  j←{⍺←0 ⋄ ⍺+0j1×⍵}

  3 j 4 ¯5.6 7.89

3J4 3J¯5.6 3J7.89

  j 4 ¯5.6 7.89

0J4 0J¯5.6 0J7.89

  sin← 1∘○
  cos← 2∘○
  Euler← {(*j ⍵) = (cos ⍵) j (sin ⍵)}

  Euler (¯0.5+?10⍴0) j (¯0.5+?10⍴0)

1 1 1 1 1 1 1 1 1 1 </syntaxhighlight>

The last expression illustrates Euler's formula on ten random numbers with real and imaginary parts in the interval $\left(-0.5,0.5\right)$.

Single recursion

The ternary construction of the Cantor set starts with the interval [0,1] and at each stage removes the middle third from each remaining subinterval:

Failed to parse (SVG (MathML can be enabled via browser plugin): Invalid response ("Math extension cannot connect to Restbase.") from server "https://wikimedia.org/api/rest_v1/":): {\displaystyle \biggl[0,1\biggr] \to}

$\left[0,{\frac {1}{3}}\right]\cup \left[{\frac {2}{3}},1\right]\to$

$\left[0,{\frac {1}{9}}\right]\cup \left[{\frac {2}{9}},{\frac {1}{3}}\right]\cup \left[{\frac {2}{3}},{\frac {7}{9}}\right]\cup \left[{\frac {8}{9}},1\right]\to \cdots$

The Cantor set of order <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> defined as a dfn:

<syntaxhighlight lang=apl>

  Cantor← {0=⍵:,1 ⋄ ,1 0 1 ∘.∧ ∇ ⍵-1}

  Cantor 0

1

  Cantor 1

1 0 1

  Cantor 2

1 0 1 0 0 0 1 0 1

  Cantor 3

1 0 1 0 0 0 1 0 1 0 0 0 0 0 0 0 0 0 1 0 1 0 0 0 1 0 1 </syntaxhighlight>

Cantor 0 to Cantor 6 depicted as black bars:

The function <syntaxhighlight lang="apl" class="" style="" inline="1">sieve ⍵</syntaxhighlight> computes a bit vector of length <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> so that bit <syntaxhighlight lang="apl" class="" style="" inline="1">i</syntaxhighlight> (for <syntaxhighlight lang="apl" class="" style="" inline="1">0≤i</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">i<⍵</syntaxhighlight>) is 1 if and only if <syntaxhighlight lang="apl" class="" style="" inline="1">i</syntaxhighlight> is a prime.

<syntaxhighlight lang=apl> sieve←{

 4≥⍵:⍵⍴0 0 1 1
 r←⌊0.5*⍨n←⍵
 p←2 3 5 7 11 13 17 19 23 29 31 37 41 43
 p←(1+(n≤×⍀p)⍳1)↑p
 b← 0@1 ⊃ {(m⍴⍵)>m⍴⍺↑1 ⊣ m←n⌊⍺×≢⍵}⌿ ⊖1,p
 {r<q←b⍳1:b⊣b[⍵]←1 ⋄ b[q,q×⍸b↑⍨⌈n÷q]←0 ⋄ ∇ ⍵,q}p

}

  10 10 ⍴ sieve 100

0 0 1 1 0 1 0 1 0 0 0 1 0 1 0 0 0 1 0 1 0 0 0 1 0 0 0 0 0 1 0 1 0 0 0 0 0 1 0 0 0 1 0 1 0 0 0 1 0 0 0 0 0 1 0 0 0 0 0 1 0 1 0 0 0 0 0 1 0 0 0 1 0 1 0 0 0 0 0 1 0 0 0 1 0 0 0 0 0 1 0 0 0 0 0 0 0 1 0 0

  b←sieve 1e9
  ≢b

1000000000

  (10*⍳10) (+⌿↑)⍤0 1 ⊢b

0 4 25 168 1229 9592 78498 664579 5761455 50847534 </syntaxhighlight>

The last sequence, the number of primes less than powers of 10, is an initial segment of OEIS: A006880. The last number, 50847534, is the number of primes less than $10^{9}$. It is called Bertelsen's number, memorably described by MathWorld as "an erroneous name erroneously given the erroneous value of $\pi (10^{9})=50847478$".

<syntaxhighlight lang="apl" class="" style="" inline="1">sieve</syntaxhighlight> uses two different methods to mark composites with 0s, both effected using local anonymous dfns: The first uses the sieve of Eratosthenes on an initial mask of 1 and a prefix of the primes 2 3...43, using the insert operator <syntaxhighlight lang="apl" class="" style="" inline="1">⌿</syntaxhighlight> (right fold). (The length of the prefix obtains by comparison with the primorial function <syntaxhighlight lang="apl" class="" style="" inline="1">×⍀p</syntaxhighlight>.) The second finds the smallest new prime <syntaxhighlight lang="apl" class="" style="" inline="1">q</syntaxhighlight> remaining in <syntaxhighlight lang="apl" class="" style="" inline="1">b</syntaxhighlight> (<syntaxhighlight lang="apl" class="" style="" inline="1">q←b⍳1</syntaxhighlight>), and sets to 0 bit <syntaxhighlight lang="apl" class="" style="" inline="1">q</syntaxhighlight> itself and bits at <syntaxhighlight lang="apl" class="" style="" inline="1">q</syntaxhighlight> times the numbers at remaining 1 bits in an initial segment of <syntaxhighlight lang="apl" class="" style="" inline="1">b</syntaxhighlight> (<syntaxhighlight lang="apl" class="" style="" inline="1">⍸b↑⍨⌈n÷q</syntaxhighlight>). This second dfn uses tail recursion.

Tail recursion

Typically, the factorial function is define recursively (as above), but it can be coded to exploit tail recursion by using an accumulator left argument: <syntaxhighlight lang=apl> fac←{⍺←1 ⋄ ⍵=0:⍺ ⋄ (⍺×⍵) ∇ ⍵-1} </syntaxhighlight>

Similarly, the determinant of a square complex matrix using Gaussian elimination can be computed with tail recursion: <syntaxhighlight lang=apl> det←{ ⍝ determinant of a square complex matrix

 ⍺←1                ⍝ product of co-factor coefficients so far
 0=≢⍵:⍺             ⍝ result for 0-by-0
 (i j)←(⍴⍵)⊤⊃⍒|,⍵   ⍝ row and column index of the maximal element
 k←⍳≢⍵
 (⍺×⍵[i;j]ׯ1*i+j) ∇ ⍵[k~i;k~j] - ⍵[k~i;j] ∘.× ⍵[i;k~j]÷⍵[i;j]

} </syntaxhighlight>

Multiple recursion

A partition of a non-negative integer $n$ is a vector $v$ of positive integers such that <syntaxhighlight lang="apl" class="" style="" inline="1">n = +⌿v</syntaxhighlight>, where the order in $v$ is not significant. For example, <syntaxhighlight lang="apl" class="" style="" inline="1">2 2</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">2 1 1</syntaxhighlight> are partitions of 4, and <syntaxhighlight lang="apl" class="" style="" inline="1">2 1 1</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">1 2 1</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">1 1 2</syntaxhighlight> are considered to be the same partition.

The partition function $P(n)$ counts the number of partitions. The function is of interest in number theory, studied by Euler, Hardy, Ramanujan, Erdős, and others. The recurrence relation

$P(n)=\sum _{k=1}^{n}(-1)^{k+1}[P(n-{\frac {1}{2}}k(3k-1))+P(n-{\frac {1}{2}}k(3k+1))]$

derived from Euler's pentagonal number theorem. Written as a dfn:

<syntaxhighlight lang=apl>

  pn  ← {1≥⍵:0≤⍵ ⋄ -⌿+⌿∇¨rec ⍵}
  rec ← {⍵ - (÷∘2 (×⍤1) ¯1 1 ∘.+ 3∘×) 1+⍳⌈0.5*⍨⍵×2÷3}

  pn 10

42

  pn¨ ⍳13    ⍝ OEIS A000041

1 1 2 3 5 7 11 15 22 30 42 56 77 </syntaxhighlight>

The basis step <syntaxhighlight lang="apl" class="" style="" inline="1">1≥⍵:0≤⍵</syntaxhighlight> states that for <syntaxhighlight lang="apl" class="" style="" inline="1">1≥⍵</syntaxhighlight>, the result of the function is <syntaxhighlight lang="apl" class="" style="" inline="1">0≤⍵</syntaxhighlight>, 1 if ⍵ is 0 or 1 and 0 otherwise. The recursive step is highly multiply recursive. For example, <syntaxhighlight lang="apl" class="" style="" inline="1">pn 200</syntaxhighlight> would result in the function being applied to each element of <syntaxhighlight lang="apl" class="" style="" inline="1">rec 200</syntaxhighlight>, which are:

<syntaxhighlight lang=apl>

  rec 200

199 195 188 178 165 149 130 108 83 55 24 ¯10 198 193 185 174 160 143 123 100 74 45 13 ¯22 </syntaxhighlight>

and <syntaxhighlight lang="apl" class="" style="" inline="1">pn 200</syntaxhighlight> requires longer than the age of the universe to compute ($7.57\times 10^{47}$ function calls to itself). The compute time can be reduced by memoization, here implemented as the direct operator (higher-order function) <syntaxhighlight lang="apl" class="" style="" inline="1">M</syntaxhighlight>:

<syntaxhighlight lang=apl> M←{

 f←⍺⍺
 i←2+'⋄'⍳⍨t←2↓,⎕cr 'f'
 ⍎'{T←(1+⍵)⍴¯1 ⋄ ',(i↑t),'¯1≢T[⍵]:⊃T[⍵] ⋄ ⊃T[⍵]←⊂',(i↓t),'⍵}⍵'

}

  pn M 200

3.973E12

  0 ⍕ pn M 200  ⍝ format to 0 decimal places
3972999029388

</syntaxhighlight>

This value of <syntaxhighlight lang="apl" class="" style="" inline="1">pn M 200</syntaxhighlight> agrees with that computed by Hardy and Ramanujan in 1918.

The memo operator <syntaxhighlight lang="apl" class="" style="" inline="1">M</syntaxhighlight> defines a variant of its operand function <syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight> to use a cache <syntaxhighlight lang="apl" class="" style="" inline="1">T</syntaxhighlight> and then evaluates it. With the operand <syntaxhighlight lang="apl" class="" style="" inline="1">pn</syntaxhighlight> the variant is:

<syntaxhighlight lang=apl> {T←(1+⍵)⍴¯1 ⋄ {1≥⍵:0≤⍵ ⋄ ¯1≢T[⍵]:⊃T[⍵] ⋄ ⊃T[⍵]←⊂-⌿+⌿∇¨rec ⍵}⍵} </syntaxhighlight>

Direct operator (dop)

Quicksort on an array <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> works by choosing a "pivot" at random among its major cells, then catenating the sorted major cells which strictly precede the pivot, the major cells equal to the pivot, and the sorted major cells which strictly follow the pivot, as determined by a comparison function <syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight>. Defined as a direct operator (dop) <syntaxhighlight lang="apl" class="" style="" inline="1">Q</syntaxhighlight>: <syntaxhighlight lang=apl>

  Q←{1≥≢⍵:⍵ ⋄ (∇ ⍵⌿⍨0>s)⍪(⍵⌿⍨0=s)⍪∇ ⍵⌿⍨0<s←⍵ ⍺⍺ ⍵⌷⍨?≢⍵}

  ⍝ precedes            ⍝ follows            ⍝ equals
  2 (×-) 8              8 (×-) 2             8 (×-) 8

¯1 1 0

  x← 2 19 3 8 3 6 9 4 19 7 0 10 15 14

  (×-) Q x

0 2 3 3 4 6 7 8 9 10 14 15 19 19 </syntaxhighlight>

<syntaxhighlight lang="apl" class="" style="" inline="1">Q3</syntaxhighlight> is a variant that catenates the three parts enclosed by the function <syntaxhighlight lang="apl" class="" style="" inline="1">⊂</syntaxhighlight> instead of the parts per se. The three parts generated at each recursive step are apparent in the structure of the final result. Applying the function derived from <syntaxhighlight lang="apl" class="" style="" inline="1">Q3</syntaxhighlight> to the same argument multiple times gives different results because the pivots are chosen at random. In-order traversal of the results does yield the same sorted array. <syntaxhighlight lang=apl>

  Q3←{1≥≢⍵:⍵ ⋄ (⊂∇ ⍵⌿⍨0>s)⍪(⊂⍵⌿⍨0=s)⍪⊂∇ ⍵⌿⍨0<s←⍵ ⍺⍺ ⍵⌷⍨?≢⍵}

  (×-) Q3 x

┌────────────────────────────────────────────┬─────┬┐ │┌──────────────┬─┬─────────────────────────┐│19 19││ ││┌──────┬───┬─┐│6│┌──────┬─┬──────────────┐││ ││ │││┌┬─┬─┐│3 3│4││ ││┌┬─┬─┐│9│┌┬──┬────────┐│││ ││ │││││0│2││ │ ││ ││││7│8││ │││10│┌──┬──┬┐││││ ││ │││└┴─┴─┘│ │ ││ ││└┴─┴─┘│ │││ ││14│15││││││ ││ ││└──────┴───┴─┘│ ││ │ │││ │└──┴──┴┘││││ ││ ││ │ ││ │ │└┴──┴────────┘│││ ││ ││ │ │└──────┴─┴──────────────┘││ ││ │└──────────────┴─┴─────────────────────────┘│ ││ └────────────────────────────────────────────┴─────┴┘

  (×-) Q3 x

┌───────────────────────────┬─┬─────────────────────────────┐ │┌┬─┬──────────────────────┐│7│┌────────────────────┬─────┬┐│ │││0│┌┬─┬─────────────────┐││ ││┌──────┬──┬────────┐│19 19│││ │││ │││2│┌────────────┬─┬┐│││ │││┌┬─┬─┐│10│┌──┬──┬┐││ │││ │││ │││ ││┌───────┬─┬┐│6│││││ │││││8│9││ ││14│15││││ │││ │││ │││ │││┌┬───┬┐│4│││ │││││ │││└┴─┴─┘│ │└──┴──┴┘││ │││ │││ │││ │││││3 3│││ │││ │││││ ││└──────┴──┴────────┘│ │││ │││ │││ │││└┴───┴┘│ │││ │││││ │└────────────────────┴─────┴┘│ │││ │││ ││└───────┴─┴┘│ │││││ │ │ │││ │││ │└────────────┴─┴┘│││ │ │ │││ │└┴─┴─────────────────┘││ │ │ │└┴─┴──────────────────────┘│ │ │ └───────────────────────────┴─┴─────────────────────────────┘ </syntaxhighlight>

The above formulation is not new; see for example Figure 3.7 of the classic The Design and Analysis of Computer Algorithms. However, unlike the pidgin ALGOL program in Figure 3.7, <syntaxhighlight lang="apl" class="" style="" inline="1">Q</syntaxhighlight> is executable, and the partial order used in the sorting is an operand, the <syntaxhighlight lang="apl" class="" style="" inline="1">(×-)</syntaxhighlight> the examples above.

Dfns with operators and trains

Dfns, especially anonymous dfns, work well with operators and trains. The following snippet solves a "Programming Pearls" puzzle: given a dictionary of English words, here represented as the character matrix <syntaxhighlight lang="apl" class="" style="" inline="1">a</syntaxhighlight>, find all sets of anagrams.

<syntaxhighlight lang=apl>

  a            {⍵[⍋⍵]}⍤1 ⊢a        ({⍵[⍋⍵]}⍤1 {⊂⍵}⌸ ⊢) a

pats apst ┌────┬────┬────┐ spat apst │pats│teas│star│ teas aest │spat│sate│ │ sate aest │taps│etas│ │ taps apst │past│seat│ │ etas aest │ │eats│ │ past apst │ │tase│ │ seat aest │ │east│ │ eats aest │ │seta│ │ tase aest └────┴────┴────┘ star arst east aest seta aest </syntaxhighlight>

The algorithm works by sorting the rows individually (<syntaxhighlight lang="apl" class="" style="" inline="1">{⍵[⍋⍵]}⍤1 ⊢a</syntaxhighlight>), and these sorted rows are used as keys ("signature" in the Programming Pearls description) to the key operator <syntaxhighlight lang="apl" class="" style="" inline="1">⌸</syntaxhighlight> to group the rows of the matrix. The expression on the right is a train, a syntactic form employed by APL to achieve tacit programming. Here, it is an isolated sequence of three functions such that <syntaxhighlight lang="apl" class="" style="" inline="1">(f g h) ⍵</syntaxhighlight> ⇔ <syntaxhighlight lang="apl" class="" style="" inline="1">(f ⍵) g (h ⍵)</syntaxhighlight>, whence the expression on the right is equivalent to <syntaxhighlight lang="apl" class="" style="" inline="1">({⍵[⍋⍵]}⍤1 ⊢a) {⊂⍵}⌸ a</syntaxhighlight>.

Lexical scope

When an inner (nested) dfn refers to a name, it is sought by looking outward through enclosing dfns rather than down the call stack. This regime is said to employ lexical scope instead of APL's usual dynamic scope. The distinction becomes apparent only if a call is made to a function defined at an outer level. For the more usual inward calls, the two regimes are indistinguishable.

For example, in the following function <syntaxhighlight lang="apl" class="" style="" inline="1">which</syntaxhighlight>, the variable <syntaxhighlight lang="apl" class="" style="" inline="1">ty</syntaxhighlight> is defined both in <syntaxhighlight lang="apl" class="" style="" inline="1">which</syntaxhighlight> itself and in the inner function <syntaxhighlight lang="apl" class="" style="" inline="1">f1</syntaxhighlight>. When <syntaxhighlight lang="apl" class="" style="" inline="1">f1</syntaxhighlight> calls outward to <syntaxhighlight lang="apl" class="" style="" inline="1">f2</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">f2</syntaxhighlight> refers to <syntaxhighlight lang="apl" class="" style="" inline="1">ty</syntaxhighlight>, it finds the outer one (with value <syntaxhighlight lang="apl" class="" style="" inline="1">'lexical'</syntaxhighlight>) rather than the one defined in <syntaxhighlight lang="apl" class="" style="" inline="1">f1</syntaxhighlight> (with value <syntaxhighlight lang="apl" class="" style="" inline="1">'dynamic'</syntaxhighlight>):

<syntaxhighlight lang=apl> which←{

 ty←'lexical'
 f1←{ty←'dynamic' ⋄ f2 ⍵}
 f2←{ty,⍵}
 f1 ⍵

}

  which ' scope'

lexical scope </syntaxhighlight>

Error-guard

The following function illustrates use of error guards: <syntaxhighlight lang=apl> plus←{

 tx←'catch all' ⋄  0::tx
 tx←'domain'    ⋄ 11::tx
 tx←'length'    ⋄  5::tx
 ⍺+⍵

}

  2 plus 3              ⍝ no errors

5

  2 3 4 5 plus 'three'  ⍝ argument lengths don't match

length

  2 3 4 5 plus 'four'   ⍝ can't add characters

domain

  2 3 plus 3 4⍴5        ⍝ can't add vector to matrix

catch all </syntaxhighlight>

In APL, error number 5 is "length error"; error number 11 is "domain error"; and error number 0 is a "catch all" for error numbers 1 to 999.

The example shows the unwinding of the local environment before an error-guard's expression is evaluated. The local name <syntaxhighlight lang="apl" class="" style="" inline="1">tx</syntaxhighlight> is set to describe the purview of its following error-guard. When an error occurs, the environment is unwound to expose <syntaxhighlight lang="apl" class="" style="" inline="1">tx</syntaxhighlight>'s statically correct value.

Dfns versus tradfns

Since direct functions are dfns, APL functions defined in the traditional manner are referred to as tradfns, pronounced "trad funs". Here, dfns and tradfns are compared by consideration of the function <syntaxhighlight lang="apl" class="" style="" inline="1">sieve</syntaxhighlight>: On the left is a dfn (as defined above); in the middle is a tradfn using control structures; on the right is a tradfn using gotos (<syntaxhighlight lang="apl" class="" style="" inline="1">→</syntaxhighlight>) and line labels.

<syntaxhighlight lang="apl">sieve←{ 4≥⍵:⍵⍴0 0 1 1 r←⌊0.5*⍨n←⍵ p←2 3 5 7 11 13 17 19 23 29 31 37 41 43 p←(1+(n≤×⍀p)⍳1)↑p b← 0@1 ⊃ {(m⍴⍵)>m⍴⍺↑1 ⊣ m←n⌊⍺×≢⍵}⌿ ⊖1,p {r<q←b⍳1:b⊣b[⍵]←1 ⋄ b[q,q×⍸b↑⍨⌈n÷q]←0 ⋄ ∇ ⍵,q}p }</syntaxhighlight>

<syntaxhighlight lang="apl">∇ b←sieve1 n;i;m;p;q;r :If 4≥n ⋄ b←n⍴0 0 1 1 ⋄ :Return ⋄ :EndIf r←⌊0.5*⍨n p←2 3 5 7 11 13 17 19 23 29 31 37 41 43 p←(1+(n≤×⍀p)⍳1)↑p b←1 :For q :In p ⋄ b←(m⍴b)>m⍴q↑1 ⊣ m←n⌊q×≢b ⋄ :EndFor b[1]←0 :While r≥q←b⍳1 ⋄ b[q,q×⍸b↑⍨⌈n÷q]←0 ⋄ p⍪←q ⋄ :EndWhile b[p]←1 ∇</syntaxhighlight>

<syntaxhighlight lang="apl">∇ b←sieve2 n;i;m;p;q;r →L10 ⍴⍨ 4<n ⋄ b←n⍴0 0 1 1 ⋄ →0 L10: r←⌊0.5*⍨n p←2 3 5 7 11 13 17 19 23 29 31 37 41 43 p←(1+(n≤×\p)⍳1)↑p i←0 ⋄ b←1 L20: b←(m⍴b)>m⍴p[i]↑1 ⊣ m←n⌊p[i]×≢b →L20 ⍴⍨ (≢p)>i←1+i b[1]←0 L30: →L40 ⍴⍨ r<q←b⍳1 ⋄ b[q,q×⍸b↑⍨⌈n÷q]←0 ⋄ p⍪←q ⋄ →L30 L40: b[p]←1 ∇</syntaxhighlight>

• A dfn can be anonymous; a tradfn must be named.
• A dfn is named by assignment (<syntaxhighlight lang="apl" class="" style="" inline="1">←</syntaxhighlight>); a tradfn is named by embedding the name in the representation of the function and applying <syntaxhighlight lang="apl" class="" style="" inline="1">⎕fx</syntaxhighlight> (a system function) to that representation.
• A dfn is handier than a tradfn as an operand (see preceding items: a tradfn must be named; a tradfn is named by embedding ...).
• Names assigned in a dfn are local by default; names assigned in a tradfn are global unless specified in a locals list.
• Locals in a dfn have lexical scope; locals in a tradfn have dynamic scope, visible in called functions unless shadowed by their locals list.
• The arguments of a dfn are named <syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> and the operands of a dop are named <syntaxhighlight lang="apl" class="" style="" inline="1">⍺⍺</syntaxhighlight> and <syntaxhighlight lang="apl" class="" style="" inline="1">⍵⍵</syntaxhighlight>; the arguments and operands of a tradfn can have any name, specified on its leading line.
• The result (if any) of a dfn is unnamed; the result (if any) of a tradfn is named in its header.
• A default value for ⍺ is specified more neatly than for the left argument of a tradfn.
• Recursion in a dfn is effected by invoking <syntaxhighlight lang="apl" class="" style="" inline="1">∇</syntaxhighlight> or <syntaxhighlight lang="apl" class="" style="" inline="1">∇∇</syntaxhighlight> or its name; recursion in a tradfn is effected by invoking its name.
• Flow control in a dfn is effected by guards and function calls; that in a tradfn is by control structures and <syntaxhighlight lang="apl" class="" style="" inline="1">→</syntaxhighlight> (goto) and line labels.
• Evaluating an expression in a dfn not ending in assignment causes return from the dfn; evaluating a line in a tradfn not ending in assignment or goto displays the result of the line.
• A dfn returns on evaluating an expression not ending in assignment, on evaluating a guarded expression, or after the last expression; a tradfn returns on <syntaxhighlight lang="apl" class="" style="" inline="1">→</syntaxhighlight> (goto) line 0 or a non-existing line, or on evaluating a <syntaxhighlight lang="apl" class="" style="" inline="1">:Return</syntaxhighlight> control structure, or after the last line.
• The simpler flow control in a dfn makes it easier to detect and implement tail recursion than in a tradfn.
• A dfn may call a tradfn and vice versa; a dfn may be defined in a tradfn, and vice versa.

History

Kenneth E. Iverson, the inventor of APL, was dissatisfied with the way user functions (tradfns) were defined. In 1974, he devised "formal function definition" or "direct definition" for use in exposition. A direct definition has two or four parts, separated by colons: <syntaxhighlight lang=apl> name : expression name : expression0 : proposition : expression1 </syntaxhighlight> Within a direct definition, <syntaxhighlight lang="apl" class="" style="" inline="1">⍺</syntaxhighlight> denotes the left argument and <syntaxhighlight lang="apl" class="" style="" inline="1">⍵</syntaxhighlight> the right argument. In the first instance, the result of <syntaxhighlight lang="apl" class="" style="" inline="1">expression</syntaxhighlight> is the result of the function; in the second instance, the result of the function is that of <syntaxhighlight lang="apl" class="" style="" inline="1">expression0</syntaxhighlight> if <syntaxhighlight lang="apl" class="" style="" inline="1">proposition</syntaxhighlight> evaluates to 0, or <syntaxhighlight lang="apl" class="" style="" inline="1">expression1</syntaxhighlight> if it evaluates to 1. Assignments within a direct definition are dynamically local. Examples of using direct definition are found in the 1979 Turing Award Lecture and in books and application papers.

Direct definition was too limited for use in larger systems. The ideas were further developed by multiple authors in multiple works but the results were unwieldy. Of these, the "alternative APL function definition" of Bunda in 1987 came closest to current facilities, but is flawed in conflicts with existing symbols and in error handling which would have caused practical difficulties, and was never implemented. The main distillates from the different proposals were that (a) the function being defined is anonymous, with subsequent naming (if required) being effected by assignment; (b) the function is denoted by a symbol and thereby enables anonymous recursion.

In 1996, John Scholes of Dyalog Limited invented direct functions (dfns). The ideas originated in 1989 when he read a special issue of The Computer Journal on functional programming. He then proceeded to study functional programming and became strongly motivated ("sick with desire", like Yeats) to bring these ideas to APL. He initially operated in stealth because he was concerned the changes might be judged too radical and an unnecessary complication of the language; other observers say that he operated in stealth because Dyalog colleagues were not so enamored and thought he was wasting his time and causing trouble for people. Dfns were first presented in the Dyalog Vendor Forum at the APL '96 Conference and released in Dyalog APL in early 1997. Acceptance and recognition were slow in coming. As late as 2008, in Dyalog at 25, a publication celebrating the 25th anniversary of Dyalog Limited, dfns were barely mentioned (mentioned twice as "dynamic functions" and without elaboration). As of 2019, dfns are implemented in Dyalog APL, NARS2000, and ngn/apl. They also play a key role in efforts to exploit the computing abilities of a graphics processing unit (GPU).

External links

• Official website, Dyalog